data ia.firstq/view=ia.firstq;
    infile Q1;
    input Flight $ Origin $ Dest $ Date : date9. 
          RevCargo : comma15.2;
run;

filename Q1 ('Month1.dat' 'Month2.dat' 'Month3.dat');

proc print data=ia.firstq;
title 'ia.firstq DATA Step View';
  format Date date9.;
run;

/* The following program appends data from 3 months.  
   The data selected is dependent on today's date. */

data ia.movingq/view=ia.movingq;
  MonNum=month(today());
  MidMon=month(intnx('month',today(),-1));
  LastMon=month(intnx('month',today(),-2));
  do i=LastMon, MidMon, MonNum; 
     NextFile="Month"||put(i,2.)||".dat";
     NextFile=compress(NextFile,' ');
	    do until (LastObs);
	      infile in filevar=NextFile end=LastObs;
	      input Flight $ Origin $ Dest $ Date : date9. RevCargo : comma15.2;
		  output;
	    end; 
  end;  
  stop;
run;  

data view=ia.movingq;
  describe;
run;

options date;

proc print data=ia.movingq;
title 'ia.movingq DATA Step View';
   var Flight Origin Date Dest RevCargo;
   format Date date9.;
run;