/*  Chapter6.sas  */

/*  C06S4D01.sas  */

/* Define the PRTLAST macro: */

%macro prtlast;
                proc print data = &syslast (obs = 5);
                  title "Listing of &syslast data set";
                run;
%mend prtlast;

/* Call the PRTLAST macro: */

proc sort data = ia.Airport out = Airport;
        by Country;
run;

%prtlast

proc sort data = ia.Employees out = Employees;
  by EmployeeID;
run;

%prtlast

proc sort data = ia.TicketAgents out = TicketAgents;
  by City;
run;

%prtlast

/*  C06S5D01.sas */

data comparison199901(keep=Month BudgetFirst BudgetBusiness
                      BudgetEconomy BudgetCargo SalesFirst
                      SalesBusiness SalesEconomy SalesCargo);
   if _n_=1 then do until (eofb);
     set ia.Budget199901 end=eofb;
     link GetMon;
     BudgetFirst + BudgetRevenueFirstClass;
     BudgetBusiness + BudgetRevenueBusiness;
     BudgetEconomy + BudgetRevenueEconomy;
     BudgetCargo + BudgetRevenueCargo;
   end;
   set ia.Sales199901 end=eofs;
   link GetMon;
   SalesFirst + SalesRevenueFirstClass;
   SalesBusiness + SalesRevenueBusiness;
   SalesEconomy + SalesRevenueEconomy;
   SalesCargo + SalesRevenueCargo;
   if eofs;
return;

GetMon:
   month=substr(SalesMonth, 1, 3);
   return;
run;