/*  Case Study 1 Solutions */
/*  Part 3a */
/*  Concatenate the ia.IAEmployees and ia.SEEmployees  data sets */

data ia.Employees;
  set ia.IAEmployees
        ia.SEEmployees;
run;

/*  OR  */

proc sql;
  create table ia.Employees as
    select * 
      from ia.IAEmployees
    outer union corr
    select *
      from ia.SEEmployees
  ;
quit;

/*  OR  */

proc append base = ia.Employees data = ia.IAEmployees;
run;

proc append base = ia.Employees data = ia.SEEmployees;
run;

/* OR */

proc sql;
  create table ia.Employees as
      select *
          from ia.IAEmployees
  ;
  insert into ia.Employees
      select *
          from ia.SEEmployees
  ;
quit;

/* Part 3b */

proc sql;
  create unique index EmployeeID
      on ia.Employees (EmployeeID);
quit;

/*  OR  */

proc datasets lib = ia nolist;
  modify Employees;
    index create EmployeeID / unique;
quit;

/*  Part 4 */

data ia.Raises;
  set ia.SelectEmployees;
  set ia.Employees key = EmployeeID;
  keep EmployeeID Jobcode Salary;
run;